CustomEvent

package com.witheringtree.controller.events
{
	import flash.events.Event;
	/**
	 * Extension of the Event class to allow you to pass parameters to the event handlers.
	 */
	public class CustomEvent extends Event
	{
		// Add custom event constants below
		public static const ACTION:String = "action";
		public var params:Object;
		/**
		 * Create a new event.
		 */
		public function CustomEvent(type:String, params:Object=null, bubbles:Boolean=false, cancelable:Boolean=false)
		{
			super(type, bubbles, cancelable);
			this.params = params;
		}
		/**
		 * Clone an created event.
		 * @return Cloned event.
		 */
		public override function clone():Event
		{
			return new CustomEvent(type, this.params, bubbles, cancelable);
		}
		/**
		 * Return event as a string.
		 * @return Returns string.
		 */
		public override function toString():String
		{
			return formatToString("CustomEvent", "params", "type", "bubbles", "cancelable");
		}
	}
}

myObject.addEventListener(CustomEvent.ACTION, doEvent);
public function doEvent(evt:CustomEvent):void
{
	Alert.show("TYPE: " + evt.type + "\nTARGET: " + evt.target + "\nFIRST CUSTOM PARAM: " + evt.params.param1 + "\nSECOND CUSTOM PARAM: " + evt.params.param2);
}
dispatchEvent(new CustomEvent(CustomEvent.ACTION, {param1:"first param", param2:"second param"}));